ICONTASK
 Windows10/11を使用していて、いろんなプログラムをインストールして使用していると、時間が経つにつれて、多くの無効または古いタスクバーの通知アイコンが、「通知のカスタマイズ」または「タスクバーに表示されるアイコンの選択」ページに、重複したアイコンや現在存在しないプログラムのアイコンなどが表示されることがあります。Windows の [通知のカスタマイズ] ダイアログで過去および現在のアイテムの一覧をクリアする方法についてご紹介します。
1: スクリプトの使用
 VBクリプトを使用して消去する方法です。現在使用しているプログラムをすべて閉じ、下記のリンクからVBスクリプトをダウンロードし、実行します。

ダウンロード clear_notification_taskbar_overflow_icons.vbs

VBSの内容

'-----------------------------------------------------------------------------
'Clears items in the Customize Notifications (Taskbar Corner Overflow icons).
'This script can be used on Windows 11, 10, 8, 7, Vista, and XP.
'Written by Ramesh Srinivasan
'Created: Feb 13, 2007
'Updated: Aug 22, 2022
'https://www.winhelponline.com/blog/
'-----------------------------------------------------------------------------

Option Explicit
Dim objWMIService, colItems, objItem, sCurrUsrName
Dim colProcList, objProcess, sNameOfUser, sUserDomain, sWel, sKey, sKey2
Dim colProperties

Dim WshShell: Set WshShell = CreateObject("WScript.Shell")
sKey = "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\"
sKey = sKey & "CurrentVersion\TrayNotify\"
sKey2= "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\TrayNotify\"
Set objWMIService = GetObject ("winmgmts:\\" & "." & "\root\cimv2")

ExitExplorerShell
WScript.Sleep(3000)
ClearOverflowIcons
WScript.Sleep(2000)
StartExplorerShell

Sub ExitExplorerShell()
   'Get curr. user name
   Set colItems = objWMIService.ExecQuery("Select * From Win32_ComputerSystem")
   For Each objItem In colItems
      sCurrUsrName = objItem.UserName
   Next
   
   'Restart the Explorer shell
   Set colProcList = objWMIService.ExecQuery _
   ("Select * from Win32_Process Where Name = 'Explorer.exe'")
   For Each objProcess In colProcList
      colProperties = objProcess.GetOwner(sNameOfUser,sUserDomain)
      If UCase(sUserDomain & "\" & sNameOfUser) = UCase(sCurrUsrName) Then
         objProcess.Terminate(1)
      End If
   Next
End Sub

Sub ClearOverflowIcons
   'Clear the Customize Notifications dialog
   On Error Resume Next
   WshShell.Regdelete sKey & "IconStreams"
   WshShell.Regdelete sKey & "PastIconsStream"
   WshShell.Regdelete sKey2 & "IconStreams"
   WshShell.Regdelete sKey2 & "PastIconsStream"
   On Error GoTo 0
End Sub

Sub StartExplorerShell
   WshShell.Run "explorer.exe"
End Sub

sWel = "For more tips and articles on Windows, visit us at:" & _
Chr(10) & Chr(10) & vbtab & "https://www.winhelponline.com/blog/"
Msgbox "Done!" & Chr(10) & Chr(10) & sWel & _
Chr(10), 64, "Taskbar Corner Overflow icons have been reset." 
2.レジストリ エディターを使用して削除

  レジストリを削除してリセットを行います。方法は次の通りです。

  1. タスクマネージャを開きます。
  2. プロセスからExplorer.exeを終了します。この後再起動しないでください。
  3. タスクバーとデスクトップアイコンは表示されませんので、タスクマネージャの「新しいタスクを実行する」から、「regedit.exe」と入力し、レジストリエディターを開きます。
  4. 次のパスに移動します。
    コンピューター\HKEY_CURRENT_USER\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
  5. IconStreamsとPastIconsStream の値を削除します。
  6. レジストリエディタを終了します。
  7. タスクマネージャの「新しいタスクを実行する」からExplorer.exeを起動します。これにより、Windows シェルが再び起動します。
  8. これにより、Windows 11を含むすべてのバージョンのWindowsのタスクバーにあるカスタマイズ通知トレイアイコンがクリアされます。